* CATIA & WS PERFORMANCE TEST, (C) EMA 2000                LM:12.06.2000
INTERNAL
  INTEGER ER,INDEX,DATA,H FORMAT 2,M FORMAT 2,S FORMAT 2,H1,M1,S1,STK,
  %       I FORMAT 2,N FORMAT 4,SUM FORMAT 9,BPLN FORMAT 4,END
  CHAR*8  FILE,USER,DATM,TIMEM,TIME
  CHAR*20 VERSIO,RELEAS,TITLE(4)
  CHAR*35 CEMA INIT '     PERFORMANCE TEST, (C) EMA 2000'
  UNDEFLM ELM,FAC(19999),AXS
PROC
  LOAD GIMNAM 1,FILE,TITLE,ER
  LET TITLE(1)='__CATIA_PERFORMANCE_'
  LET TITLE(2)='TEST_(MORE INFO AVAI'
  LET TITLE(3)='LABLE ON: WWW.EMA3.C'
  LET TITLE(4)='OM)_________________'
  MSG 'TEST MODEL WRITE ....              '//CEMA
  LOAD GIMWRI 1,FILE,TITLE,0,1,ER
  BLOCKIF(ER NE 0)THEN
LABEL ERRWRITE
    BEEP
    MSG 'CAN NOT SAVE MODEL, YES:END.       '//CEMA YES
    EXIT
  ENDIF
  MSG 'TEST MODEL READ ....               '//CEMA
  LOAD GIMREA 1,FILE,TITLE,INDEX,DATA,ER
  BLOCKIF(ER NE 0)THEN
LABEL ERRREAD
    BEEP
    MSG 'CAN NOT OPEN MODEL, YES:END.       '//CEMA YES
    EXIT
  ENDIF
  LOAD GIMVER 1,USER,DATM,TIMEM,VERSIO,RELEAS,ER
  LET H=CONV(TIMEM(1:2))
  LET M=CONV(TIMEM(4:5))
  LET S=CONV(TIMEM(7:8))
  LOAD GUMSEL 1,4,'*FAC',5,1,1,1,STK,ER
  BLOCKIF(ER EQ 0) THEN
    LET N=0
    DO
      LOAD GUSPOP STK,ELM,I,ER
      IF(I EQ 0)AND(TYPP(ELM)EQ 6)LET N=N+1
      IF(I EQ 0)AND(TYPP(ELM)EQ 6)LET FAC(N)=ELM
    WHILE(I EQ 0)
    BLOCKIF(N NE 0)THEN
      LOAD GBUCOH 1,0,0,2,I,ER
      LET I=0
      DO
        LOAD GISBPL 1,I,BPLN,END,ER
        MSGCNTL 'PLEASE WAIT ....                   '//
        %       'NUM OF BACKGROUND PLN: '//CHCONV(BPLN)
        MSG 'PROJECT FACES TO ALL VIEWS         '//CEMA
        IF(END EQ 0)LOAD GICBPL 1,BPLN,ER
        IF(END EQ 0)LOAD GBLDVO 1,N,FAC,1,I,STK,ER
        IF(END EQ 0)LOAD GIMTAS 1,ER
        IF(END EQ 0)LET SUM=SUM+I
        LET I=BPLN
      WHILE(END EQ 0)
    ELSE
      BRANCH ERROR
    ENDIF
  ELSE
LABEL ERROR
    BEEP
    MSGCNTL 'NO FAC FOUND FOR SPC -> DR2 PROJ.'
    MSG 'YES:END                            '//CEMA YES
    EXIT
  ENDIF
  LET I=1
  LOAD GIRMCM 1,N,ER
  DO
    MSG 'GRAPHICS TEST '//CHCONV(I)//'/10 ....           '//CEMA
    LET I=I+1
    MSGCNTL 'no hidden line removal (nhr)'
    LOAD GICMVI 1,1,ER
    MSGCNTL 'hidden line removal (hlr)'
    LOAD GICMVI 1,2,ER
    MSGCNTL 'dynamic shading (shd)'
    LOAD GICMVI 1,3,ER
    MSGCNTL 'dynamic hidden line removal (hrd)'
    LOAD GICMVI 1,4,ER
  WHILE(I LE 10)
  LOAD GICMVI 1,N,ER
  MSG 'TEST MODEL WRITE ....              '//CEMA
  LOAD GIMWRI 1,FILE,TITLE,0,1,ER
  IF(ER NE 0)THEN ERRWRITE
  MSG 'TEST MODEL READ ....               '//CEMA
  LOAD GIMREA 1,FILE,TITLE,INDEX,DATA,ER
  IF(ER NE 0)THEN ERRREAD
  LOAD GIMVER 1,USER,DATM,TIMEM,VERSIO,RELEAS,ER
  LET H1=CONV(TIMEM(1:2))
  LET M1=CONV(TIMEM(4:5))
  LET S1=CONV(TIMEM(7:8))
  LET H=H1-H
  LET M=M1-M
  LET S=S1-S
  LET TIME=CHCONV(H)//':'//CHCONV(M)//':'//CHCONV(S)
  LET N=H*60*60+M*60+S
  BEEP
  MSGCNTL 'GENERATED ELEMENTS: '//CHCONV(SUM)
  MSG 'ELAPSED TIME:'//CHCONV(N)//' SEC, YES:END     '//CEMA YES
  LOAD GIFDEL FILE,TITLE,ER
END